@auto[]
^use[padparser.p]

#####################################################################
# 
#
@bodyMain[]

<h2>Submit or update software</h2> 
<img src="$ROOT/pics/line1.gif" width="548" height="4" vspace=2><br> 

^switch[$form:do]{
	^case[submit]{
		^if(def $form:padURL){
			^blockSubmitPAD[$form:padURL;$form:category]
		}{
			PAD URL still not specified!
		}
	}
	^case[remove]{
		To remove the program from our listing send an email to 
		<SCRIPT language="JavaScript">
			var p1 = 'removepad'^;
			var p2 = 'realfiletools'^;
			var p3 = 'com'^;
			
			document.write('<A href="mail'+'to:'+p1+'@'+p2+'.'+p3+'">')^;
			document.write(p1+'@'+p2+'.'+p3+'</A>')^;
			
		</SCRIPT>
		specifying program name as it appears in our listings.
	}
	^case[DEFAULT]{
		^blockSubmitForm[]
	}
}

#####################################################################
# Осуществляем сабмит
#
@blockSubmitPAD[padURL;catID][f;icon;shot;img;PAD;companyHash;CID;PID;programHash;descHash]
<B>Submitting...</B><BR>

^try{
	$f[^fileLoad[binary;$padURL]]
	
	$PAD[^padparser::init[^taint[as-is][$f.text]]]

	^if(def $PAD && def ^PAD.isValidPad[]){
	
#		Информация о компании
		$companyHash[^PAD.getCompanyInfo[]]
#		Информация о программе
		$programHash[^PAD.getProgramInfo[]]
		$descHash[^PAD.getProgramDescriptions[English]]
		
		<SMALL>
		^if(def $programHash.Application_Icon_URL){
			^try{
				$icon[^fileLoad[binary;$programHash.Application_Icon_URL]]
				Application icon loaded ($icon.size bytes)<BR>
				^if($icon.size > 10000){
					$errors[$errors<BR>Icon size exceeds 10Kb!]
					$icon[]
				}
			}{
				$exception.handled(1)
				$errors[$errors<BR>Unable to fetch Application Icon file from: $programHash.Application_Icon_URL]
			}
		}
		^if(def $programHash.Application_Screenshot_URL){
			^try{
				$shot[^fileLoad[binary;$programHash.Application_Screenshot_URL]]
				Application screenshot loaded ($shot.size bytes)<BR>
				^if($shot.size > 256000){
					$errors[$errors<BR>Screenshot size exceeds 250Kb!]
					$shot[]
				}{
					$img[^image::measure[$shot]]
				}
			}{
				$exception.handled(1)
				$errors[
					$errors<BR>Unable to fetch Application Screenshot file from: $programHash.Application_Screenshot_URL 
					($exception.type^: <EM>$exception.comment ($exception.source)</EM>)
				]
			}
		}
		</SMALL>
		
		^if(!def $errors){
#			Сабмит информации о компании
			Submitting company information...<BR>
			$CID[^DATA.submitCompany[$companyHash]]
			^if($CID > 0){
#				Формируем дополнительные поля информации о программе
				Submitting program...<BR>
				$programHash.Company_ID[$CID]
				$programHash.Program_Nick[^title2Nick[$programHash.Program_Name]]
				$programHash.Program_User_Category($catID)
				$programHash.Program_True_Category(0)
				$programHash.Site_Priority(0)
				$programHash.Site_Submitted[^getDateNow[]]
				$programHash.Site_Screenshot_Width(^if(def $img){$img.width}{100})
				$programHash.Site_Screenshot_Height(^if(def $img){$img.height}{10})
			
				$PID[^DATA.submitProgram[$programHash;$descHash]]
			
#				Сохраняем PAD в папку
				^if(^PID.int(-1) != -1){
					^PAD.saveTo[$ROOT/db/pad/${PID}.xml]
				}
#				Сохраняем иконку и скриншот
				^if(def $icon){
					^icon.save[binary;$ROOT/db/icon/${PID}.^file:justext[$icon.name]]
				}
				^if(def $shot){
					^shot.save[binary;$ROOT/db/screenshot/${PID}.^file:justext[$shot.name]]
				}
			}{
				$errors[$errors<BR>Error submitting company info!]
			}
		}
	}{
		$errors[$errors<BR>Invalid PAD file!]
	}
	^mail:send[ 
		$.from[RFT Robot <robot@realfiletools.com>] 
		$.to[$submitMail] 
		$.subject[Submission: $programHash.Program_Name $programHash.Program_Version] 
		$.text[
Hi there,

A new submission on RealFileTools:

$programHash.Program_Name $programHash.Program_Version
by $companyHash.Company_Name

Description:

$descHash.Char_Desc_250

--
Best regards,
RFT Robot			
		] 
	] 
}{
#	$exception.handled(1)
	$errors[
		$errors<BR>Fatal error fetching PAD file: $padURL<BR> $exception.type^: <EM>$exception.comment ($exception.source)</EM><BR>
		$exception.source ($exception.file, line: $exception.lineno, col: $exception.colno)		
	]
}

^if(def $errors){
	<B>An error occured while submitting your application, webmasters have been notified</B><BR>
	$errors
	^mail:send[ 
		$.from[RFT Robot <robot@realfiletools.com>] 
		$.to[$bugrepMail] 
		$.subject[Error while submitting: $programHash.Program_Name $programHash.Program_Version] 
		$.text[
Hi there,

Error message:

$errors

--
Best regards,
RFT Robot			
		] 
	] 
}{
	<BR>
	<BIG>Thanks for submitting $programHash.Program_Name!</BIG><BR>
	It will appear in our listings after approvement
}

#####################################################################
# Формирует форму сабмита
#
@blockSubmitForm[]
<DIV id="anyform">
	<FORM name="submit" action="$request:uri" method="POST">
	<INPUT type="hidden" name="do" value="submit">
	<TABLE width="100%" cellpadding="2" cellspacing="1" border="0">
		<TR>
			<TD><STRONG>Choose category:</STRONG></TD>
			<TD>^blockSubmitCats[]</TD>
		</TR>
		<TR>
			<TD><STRONG>Your PAD URL:</STRONG></TD>
			<TD><INPUT type="text" name="padURL" value="http://" size="40"></TD>
		</TR>
		<TR>
			<TD>&nbsp^;</TD>
			<TD><INPUT type="submit" value="Submit program"><BR>
			<A href="addpad.htm?do=remove">Remove PAD</A>
			</TD>
		</TR>
	</TABLE>
	</FORM>
</DIV>

#####################################################################
# Формирует список категорий
#
@blockSubmitCats[]
<SELECT name="category">
	^DATA.mainCats.menu{
		^DATA.subCats.[$DATA.mainCats.CID].menu{
			<OPTION value="$DATA.subCats.[$DATA.mainCats.CID].CID">$DATA.mainCats.Title :: $DATA.subCats.[$DATA.mainCats.CID].Title</OPTION>
		}
	}
</SELECT>